[FAQ] "Not an Autodesk path" 설치 오류 해결 가이드

대상: MZP 자동 설치 시 Security violation: Not an Autodesk path 에러가 발생하는 경우

1. 에러 증상

MZP 파일을 통한 자동 설치 시, 아래와 같은 보안 에러가 발생하며 설치가 중단됩니다.

Security violation: Not an Autodesk path

2. 발생 원인

3ds Max의 User Scripts 경로에는 두 가지 유형이 있습니다.

사내 보안 규정 등에 의해 User Scripts 경로가 Documents 방식으로 설정된 환경에서 보안 검증이 해당 경로를 인식하지 못해 발생합니다.

이 문제는 향후 업데이트에서 수정될 예정입니다.

3. 수동 설치 방법

Step 1. MZP 파일 압축 해제

MZP 파일의 확장자를 .zip으로 변경한 후 압축을 해제합니다.

예)  fast_ref_v1_0_3_max2025_260213.mzp
  → fast_ref_v1_0_3_max2025_260213.zip

참고: MZP 파일은 내부적으로 ZIP 형식입니다. 확장자만 바꾸면 일반 압축 프로그램으로 열 수 있습니다.

Step 2. 설치 경로 확인

3ds Max를 열고 MAXScript Listener (F11 키)에서 아래 명령어를 입력 후 Enter를 누릅니다.

getDir #userScripts

출력된 경로가 파일을 복사할 설치 대상 경로입니다.

예시 결과:
  "C:\Users\사용자이름\Documents\3ds Max 2025\scripts"
  "C:\Users\사용자이름\AppData\Local\Autodesk\3dsMax\2023 - 64bit\ENU\scripts"

Step 3. 패키지 폴더 복사

압축 해제한 폴더 안에 있는 os_fast_ref_package 폴더를, Step 2에서 확인한 scripts 경로에 그대로 복사합니다.

복사 후 결과 예시:
  C:\Users\...\scripts\os_fast_ref_package\

주의: os_fast_ref_package 폴더 자체를 통째로 복사해야 합니다. 폴더 안의 파일만 복사하면 안 됩니다.

Step 4. 매크로 및 메뉴 등록

3ds Max의 MAXScript Listener (F11 키)에서 아래 스크립트를 전체 선택 → 복사 → 붙여넣기 후 Enter를 눌러 실행합니다.

이 스크립트는 3ds Max 버전을 자동 감지하여 동작합니다.

(
    local scriptsDir = getDir #userScripts
    local macrosDir = getDir #userMacros
    local startupDir = getDir #userStartupScripts
    local toolDir = scriptsDir + "\\os_fast_ref_package\\"

    -- 3ds Max 버전 감지 (27000 = 2025, 26000 = 2024, 25000 = 2023)
    local maxVer = (maxVersion())[1]
    local is2025orLater = maxVer >= 27000

    if not (doesDirectoryExist toolDir) then (
        messageBox "os_fast_ref_package 폴더가 scripts 경로에 없습니다.\n먼저 Step 3을 완료해주세요." title:"오류"
    ) else (
        -- 매크로 생성
        local macroFile = macrosDir + "\\os_fast_ref.mcr"
        local toolDirSlash = substituteString toolDir "\\" "/"
        local pyCode = "import sys; tool_dir = r'" + toolDirSlash + "'; sys.path.insert(0, tool_dir) if tool_dir not in sys.path else None; from os_fast_ref.main import openWindow; openWindow()"

        local f = createFile macroFile
        format "macroScript Osfastref\n" to:f
        format "    category:\"OtakuSolutions_Tools\"\n" to:f
        format "    toolTip:\"os_fast_ref\"\n" to:f
        format "    buttonText:\"os_fast_ref\"\n" to:f
        format "(\n" to:f
        format "    python.Execute \"%\"\n" pyCode to:f
        format ")\n" to:f
        close f
        macros.load macroFile
        print ("Macro created: " + macroFile)

        if is2025orLater then (
            -- 3ds Max 2025+: 메뉴 자동 등록 스크립트 복사
            local menuSrc = toolDir + "_register_menu.ms"
            local menuDst = startupDir + "\\os_fast_ref_menu.ms"
            if doesFileExist menuSrc then (
                copyFile menuSrc menuDst
                print ("Menu script copied: " + menuDst)
            ) else (
                print ("_register_menu.ms not found - menu registration skipped")
            )

            messageBox "설치 완료! 3ds Max를 재시작해주세요.\n\n재시작 후:\n  Main Menu > OS Tools > os_fast_ref" title:"os_fast_ref 설치 완료"
        ) else (
            -- 3ds Max 2022~2024: Customize UI 안내
            messageBox "설치 완료! 3ds Max를 재시작해주세요.\n\n실행 방법:\n  Customize > Customize User Interface\n  Category: OtakuSolutions_Tools\n  Button: os_fast_ref\n\n위 버튼을 툴바에 드래그하여 사용하세요." title:"os_fast_ref 설치 완료"
        )
    )
)

실행이 정상적으로 완료되면 아래와 같은 완료 메시지가 표시됩니다.

Step 5. 3ds Max 재시작

3ds Max를 완전히 종료 후 다시 실행합니다.

Step 6. 실행 확인

4. FAQ

Q. Step 4에서 "os_fast_ref_package 폴더가 scripts 경로에 없습니다" 라고 뜹니다.

→ Step 3에서 os_fast_ref_package 폴더가 정확한 위치에 복사되었는지 확인해주세요. getDir #userScripts 로 출력된 경로 바로 아래에 폴더가 있어야 합니다.

Q. 재시작 후에도 OS Tools 메뉴가 보이지 않습니다. (2025)

→ Customize → Customize User Interface → Category: OtakuSolutions_Tools 에서 os_fast_ref 버튼을 직접 툴바에 드래그하여 사용할 수 있습니다.

5. 문의

설치 중 문제가 발생하거나 궁금한 사항이 있으시면 언제든지 연락 주세요.

• OtakuSolutions 고객지원