[FAQ] "Not an Autodesk path" 安装错误解决指南

适用于：MZP 自动安装时出现 "Security violation: Not an Autodesk path" 错误的情况

1. 错误症状

通过 MZP 文件自动安装时，会出现以下安全错误并中断安装。

Security violation: Not an Autodesk path

2. 发生原因

3ds Max 的 User Scripts 路径有两种类型。

当 User Scripts 路径因公司内部安全规定等设置为 Documents 方式时，安全验证无法识别该路径而导致此错误。

此问题计划在未来的更新中修复。

3. 手动安装方法

Step 1. 解压 MZP 文件

将 MZP 文件的扩展名改为 .zip，然后解压。

예)  fast_ref_v1_0_3_max2025_260213.mzp
  → fast_ref_v1_0_3_max2025_260213.zip

注意：MZP 文件内部为 ZIP 格式。只需更改扩展名即可用普通解压软件打开。

Step 2. 确认安装路径

打开 3ds Max，在 MAXScript Listener（F11 键）中输入以下命令后按 Enter。

getDir #userScripts

输出的路径即为文件复制的安装目标路径。

예시 결과:
  "C:\Users\사용자이름\Documents\3ds Max 2025\scripts"
  "C:\Users\사용자이름\AppData\Local\Autodesk\3dsMax\2023 - 64bit\ENU\scripts"

Step 3. 复制软件包文件夹

将解压文件夹中的 os_fast_ref_package 文件夹直接复制到 Step 2 中确认的 scripts 路径下。

복사 후 결과 예시:
  C:\Users\...\scripts\os_fast_ref_package\

注意：必须整个复制 os_fast_ref_package 文件夹。不能只复制文件夹内的文件。

Step 4. 注册宏和菜单

在 3ds Max 的 MAXScript Listener（F11 键）中，全选以下脚本 → 复制 → 粘贴，然后按 Enter 执行。

此脚本会自动检测 3ds Max 版本并相应运行。

(
    local scriptsDir = getDir #userScripts
    local macrosDir = getDir #userMacros
    local startupDir = getDir #userStartupScripts
    local toolDir = scriptsDir + "\\os_fast_ref_package\\"

    -- 3ds Max 버전 감지 (27000 = 2025, 26000 = 2024, 25000 = 2023)
    local maxVer = (maxVersion())[1]
    local is2025orLater = maxVer >= 27000

    if not (doesDirectoryExist toolDir) then (
        messageBox "os_fast_ref_package 폴더가 scripts 경로에 없습니다.\n먼저 Step 3을 완료해주세요." title:"오류"
    ) else (
        -- 매크로 생성
        local macroFile = macrosDir + "\\os_fast_ref.mcr"
        local toolDirSlash = substituteString toolDir "\\" "/"
        local pyCode = "import sys; tool_dir = r'" + toolDirSlash + "'; sys.path.insert(0, tool_dir) if tool_dir not in sys.path else None; from os_fast_ref.main import openWindow; openWindow()"

        local f = createFile macroFile
        format "macroScript Osfastref\n" to:f
        format "    category:\"OtakuSolutions_Tools\"\n" to:f
        format "    toolTip:\"os_fast_ref\"\n" to:f
        format "    buttonText:\"os_fast_ref\"\n" to:f
        format "(\n" to:f
        format "    python.Execute \"%\"\n" pyCode to:f
        format ")\n" to:f
        close f
        macros.load macroFile
        print ("Macro created: " + macroFile)

        if is2025orLater then (
            -- 3ds Max 2025+: 메뉴 자동 등록 스크립트 복사
            local menuSrc = toolDir + "_register_menu.ms"
            local menuDst = startupDir + "\\os_fast_ref_menu.ms"
            if doesFileExist menuSrc then (
                copyFile menuSrc menuDst
                print ("Menu script copied: " + menuDst)
            ) else (
                print ("_register_menu.ms not found - menu registration skipped")
            )

            messageBox "설치 완료! 3ds Max를 재시작해주세요.\n\n재시작 후:\n  Main Menu > OS Tools > os_fast_ref" title:"os_fast_ref 설치 완료"
        ) else (
            -- 3ds Max 2022~2024: Customize UI 안내
            messageBox "설치 완료! 3ds Max를 재시작해주세요.\n\n실행 방법:\n  C

ustomize > Customize User Interface\n  Category: OtakuSolutions_Tools\n  Button: os_fast_ref\n\n위 버튼을 툴바에 드래그하여 사용하세요." title:"os_fast_ref 설치 완료"
        )
    )
)

执行正常完成后，会显示如下完成消息。

Step 5. 重启 3ds Max

完全关闭 3ds Max 后重新启动。

Step 6. 确认运行

4. 常见问题

Q. 在 Step 4 中提示"os_fast_ref_package 文件夹不在 scripts 路径中"。

→ 请确认 os_fast_ref_package 文件夹在 Step 3 中已正确复制到指定位置。文件夹必须位于 getDir #userScripts 输出路径的正下方。

Q. 重启后仍看不到 OS Tools 菜单。(2025)

→ 前往 Customize → Customize User Interface → Category: OtakuSolutions_Tools，将 os_fast_ref 按钮直接拖到工具栏即可使用。

5. 联系我们

如果安装过程中遇到问题或有任何疑问，请随时联系我们。

• OtakuSolutions 客户支持