무릎 방향 문제(Calf_Cor)

안녕하세요! 늘 저희 툴에 관심 가져주셔서 감사드립니다.

해당 부분은 더블 니 트위스트 버그로 확인하였으며, 제보해 주셔서 정말 감사드립니다.
다음 빌드에 반영하여 배포하도록 하겠습니다.

우선 아래 MaxScript를 실행하시면 해당 이슈가 해결됩니다.
(노드 이름을 바꾸지 않았다는 가정입니다.)

혹시 또 문제가 발생하시면 언제든지 연락 주세요!

-- MaxScript (assumes default node names were not renamed)
(
    local sides = #("L", "R")

    fn requireNode name = (
        local n = getNodeByName name
        if n == undefined do throw ("node missing: " + name)
        n
    )

    fn applyCalf50Orient side = (
        local dest = requireNode ("DrvPt_" + side + "_Calf_50")
        local tgts = #(
            requireNode ("DrvPt_" + side + "_Calf"),
            requireNode ("DrvPt_" + side + "_ThighNoTwist")
        )

        local oc = Orientation_Constraint()
        dest.rotation.controller = oc
        oc.relative = false

        local n = oc.getNumTargets()
        for i = n to 1 by -1 do try (oc.deleteTarget i) catch ()

        for t in tgts do oc.appendTarget t 50.0
        try (oc.weight[1] = 50.0) catch ()
        try (oc.weight[2] = 50.0) catch ()

        format "ok  %  targets=% %\n" dest.name tgts[1].name tgts[2].name
    )

    undo "OrientConstraint Calf_50 L/R" on (
        for side in sides do applyCalf50Orient side
    )
)